je voudrais simplement reconstruire les packages complets à partir des sources comme cela devrait être possible
J'ai donc commencé par récupérer les sources (via SVN, j'ai compris que la repo CVS n'était pas à jour)
ça compile sans problème, sauf les setups, d'où mes questions
* pour le setup de UltraVNC
les sources ne sont pas à jour dans SVN de plus, il faut recopier les binaires "à la main" dans un répertoire .\src pour que cela puisse fonctionner
* pour le packaging SC
grâce à vos différentes informations, j'ai compris comment cela était packagé (7z + upx)
je voudrais donc au final mettre tout cela en musique pour qu'un bon vieux script
* génère les binaires
* génère le pachage uvnc
* génère le package SC
pendant que je fais autre chose
pour info, voici 3 scripts "en l'état" pour générer le package SC à partir des sources.
Ils ne sont d'aucune utilité si vous n'avez pas l'intention de compiler les sources évidemment.
*********************************************************
make-sc-all.cmd : génère le package debug et release
@echo off
setlocal
if exist winvncsc-debug.exe del winvncsc-debug.exe
if exist winvncsc-release.exe del winvncsc-release.exe
call make-sc-all-bin.cmd
if errorlevel 1 goto onerror
make-sc-package.cmd .\bin\debug winvncsc-debug.exe
if errorlevel 1 goto onerror
make-sc-package.cmd .\bin\release winvncsc-release.exe
if errorlevel 1 goto onerror
goto exit
:onerror
echo %0 failed
goto exit
:exit
endlocal
************************************************************
make-sc-all-bin.cmd : est appelé par make-sc-all.cmd pour générer les .exe
@echo off
rem make-sc-all-bin.cmd
setlocal
if not exist .\bin\debug md .\bin\debug
if errorlevel 1 goto onerror
if not exist .\bin\release md .\bin\release
if errorlevel 1 goto onerror
msdev .\winvnc\winvnc.dsw /out winvnc-build.log /make "winvncsc - Win32 Debug" /rebuild
if errorlevel 1 goto onerror
msdev .\winvnc\winvnc.dsw /out vnchooks-build.log /make "vnchooks - Win32 Debug" /rebuild
if errorlevel 1 goto onerror
copy /b .\winvnc\winvncsc\Debug\winvnc2.exe .\bin\debug\winvnc.exe > nul
if errorlevel 1 goto onerror
copy /b .\winvnc\winvncsc\Debug\winvnc2.exe .\bin\release\winvnc.exe > nul
if errorlevel 1 goto onerror
copy /b .\winvnc\Debug\vnchooks.dll .\bin\debug > nul
if errorlevel 1 goto onerror
copy /b .\winvnc\Debug\vnchooks.dll .\bin\release > nul
if errorlevel 1 goto onerror
copy /b external\helpdesk.txt .\bin\debug > nul
if errorlevel 1 goto onerror
copy /b external\background.bmp .\bin\debug > nul
if errorlevel 1 goto onerror
copy /b external\icon1.ico .\bin\debug > nul
if errorlevel 1 goto onerror
copy /b external\icon2.ico .\bin\debug > nul
if errorlevel 1 goto onerror
copy /b external\logo.bmp .\bin\debug > nul
if errorlevel 1 goto onerror
copy /b external\helpdesk.txt .\bin\release > nul
if errorlevel 1 goto onerror
copy /b external\background.bmp .\bin\release > nul
if errorlevel 1 goto onerror
copy /b external\icon1.ico .\bin\release > nul
if errorlevel 1 goto onerror
copy /b external\icon2.ico .\bin\release > nul
if errorlevel 1 goto onerror
copy /b external\logo.bmp .\bin\release > nul
if errorlevel 1 goto onerror
goto exit
:onerror
echo %0 failed
goto exit
:exit
endlocal
**************************************************************************************
make-sc-package.cmd : génère l'autoextractible, est appelé par make-sc-all.cmd
@echo off
setlocal
rem upx.exe available ? (see
http://upx.sourceforge.net)
upx -V 1>nul 2>nul
if errorlevel 1 goto onerror
rem 7z.exe available ? (see
http://www.7-zip.org/)
set PATH=%PATH%;%ProgramFiles%\7-Zip;
7z >nul 2>nul
if errorlevel 1 goto onerror
rem 7zS.sfx available ? (see "extra package" of 7z)
if not exist "%ProgramFiles%\7-Zip\7zS.sfx" goto onerror
if "%1" == "" goto usage
if not exist "%1" goto usage
if "%2" == "" goto usage
set BINPATH=%1
set PACKAGE=%2
rem cleaning
if exist ~package.7z del ~package.7z
if exist ~config.txt del ~config.txt
if exist %PACKAGE% del %PACKAGE%
echo ;!@Install@!UTF-8!> ~config.txt
echo RunProgram="winvnc.exe">> ~config.txt
echo ;!@InstallEnd@!>> ~config.txt
7z a -m9=LZMA ~package.7z "%cd%\%BINPATH%\background.bmp" "%cd%\%BINPATH%\helpdesk.txt" "%cd%\%BINPATH%\icon1.ico" "%cd%\%BINPATH%\icon2.ico" "%cd%\%BINPATH%\logo.bmp" "%cd%\%BINPATH%\vnchooks.dll" "%cd%\%BINPATH%\winvnc.exe" > nul
if errorlevel 1 goto onerror
copy /b "%ProgramFiles%\7-Zip\7zS.sfx" + ~config.txt + ~package.7z %PACKAGE% >nul
if errorlevel 1 goto onerror
upx.exe -9 %PACKAGE% >nul
if errorlevel 1 goto onerror
goto exit
:usage
echo Usage: make-sc-package binary-path outputfile
echo binary-path : relative path that contains binary files
echo outputfile : name of the package
echo ex : make-sc-package .\mybindirectory myscpackage.exe
cd ~toForceErrorLevel 2>nul
goto exit
:onerror
echo %0 failed
goto exit
:exit
endlocal
